function err2mass,jj,hh,kk
; this function returns reasonable values for magnitude errors associated
; with 2MASS J,H,K magnitudes.
; If magnitudes are out of reasonable range, very large errors are assigned.

; constants
mingood=1.
maxgood=19.
baderr=30.              ; assumed error for bad data
smgoodh=5.2             ; mag at which errors jump for saturated stars
smgoodj=4.6
smgoodk=4.3
smerr=0.25
re=[.01,.013,.01]       ; mag errors for bright stars in each filter
cc=[4.,19.,50.]         ; constants for magnitude-dependent part of error
mexp=0.2                ; magnitude exponent for mag-dependent error

; test for data in bad ranges
if(jj lt mingood or jj gt maxgood or hh lt mingood or hh gt maxgood or $
    kk lt mingood or kk gt maxgood) then begin
  merrs=[baderr,baderr,baderr]
  goto,fini
endif

; evaluate standard fits
inten=1.e8*10.^(-0.4*[jj,hh,kk])
errs=sqrt(cc*inten^mexp+re^2*inten^2)
relerrs=errs/inten
merrs=2.5*alog10(1.+relerrs)

; check for bright mags in intermediate range
if(jj le smgoodj) then merrs(0)=smerr
if(hh le smgoodh) then merrs(1)=smerr
if(kk le smgoodk) then merrs(2)=smerr

fini:
return,merrs
end