PRO omi_solarcomposite_read, funit, datfile, nxtr, npts, solcomp, wvls

; =================================================================
;         IDL routine to read OMI composite solar spectra
; =================================================================
;
; ----------------------------
; List of subroutine arguments
; ----------------------------
;
;   Input:
;
;      funit ............ file unit number  [INT]
;      datfile .......... name of data file [STR]
;
;   Output:
;
;   nxtr ................ Cross-track dimension    [INT]
;   npts ................ Number of spectral point [LON]
;   solcomp ............. Solar Composite          [DBL(nxtr,npts)]
;   wvls ................ Wavelengths              [FLT(npts)]
; 
; =================================================================

CLOSE, funit

nxtr = 0 & npts = 0L & tmp1 = 0.0 & tmp2 = 0.0 & snorm = 0.0D0

OPENR, funit, datfile
READF, funit, nxtr, npts, tmp1, tmp2, snorm

wvls    = FLTARR(npts)
solcomp = DBLARR(nxtr,npts)

tmps    = DBLARR(nxtr)
FOR ipts = 0, npts-1 DO BEGIN
   READF, funit, tmp1, tmps
   wvls   (ipts)   = tmp1
   solcomp(*,ipts) = tmps(*)
ENDFOR
solcomp = solcomp * snorm

CLOSE, funit

END