pro m67_basel_colors,ra,dec,v,bmv,teff,logg,bas_colors,names,v1=v1,mix=mix
; This routine returns synthetic colors for observed stars in M67,
; obtained by using m67_props to estimate teff and logg, and then
; using these values to interpolate into the synthetic colors table
; (for logz=-0.1, ext=0.25) ~/basel/m67_survey.sav.  String representations
; of the names of the colors are returned in array names.
; If keyword v1 is set, observations come from the older Latham teff and
; coarse logg, combined with Montgomery photometry.
; If v1 is not set, teff and logg come from soeren's more recent spectroscopic
; fits.
; If keyword mix is set, both new and old observations are obtained, and the
; old ones are used to provide 4 stars at the redmost end of the color range.

; get the M67 teff, logg derived from observations
; use v1 to choose between newer values for 116 stars from Seoren Meibohm
; and older 190 stars from Latham + Montgomery.
if(keyword_set(v1) or keyword_set(mix)) then begin
  m67_props,ra,dec,v,bmv,teffo,loggo,logzo,exto
endif
if(keyword_set(mix)) then begin
  s=where(bmv gt 1.2,ns)
  raa=ra(s)
  deca=dec(s)
  va=v(s)
  bmva=bmv(s)
  teffa=teffo(s)
  logga=loggo(s)
  logza=logzo(s)
  exta=exto(s)
endif

if(not keyword_set(v1) or keyword_set(mix)) then begin
  rd_soeren2_m67,ra,dec,v,bmv,teffo,tef2,loggo,logzo,vsini
  nst=n_elements(ra)
  exto=fltarr(nst)+3.1*0.09         ; estimate of extinction, from E_B-V = 0.09
endif

if(keyword_set(mix)) then begin
  ra=[ra,raa]
  dec=[dec,deca]
  v=[v,va]
  bmv=[bmv,bmva]
  teffo=[teffo,teffa]
  loggo=[loggo,logga]
  logzo=[logzo,logza]
  exto=[exto,exta]
  nst=n_elements(ra)
endif

; get the synthetic color table, convert it into a 2-dimensional array
; This table spans 3500-6500K in 250K steps, logg is 0.5 to 5.0 in 0.5 steps
restore,'~/d/basel/m67_survey3.sav'
;restore,'/local/d/timbrown/basel/m67_survey.sav'
ctab=fltarr(9,13,10)            ; colors, teff, log(g)
for i=0,12 do begin
  tt=3500.+250.*i
  for j=0,9 do begin
    ll=0.5+0.5*j
    s=where(teff eq tt and logg eq ll,ns)
    if(ns eq 1) then ctab(*,i,j)=colors(*,s)
  endfor
endfor

; make indices into the table for each star
ix=(teffo-3500.)/250.
iy=(loggo-0.5)/0.5

; make ouyput array, fill it up
nst=n_elements(ra)
bas_colors=fltarr(nst,9)
for i=0,8 do begin
  tabl=reform(ctab(i,*,*),13,10)
  bas_colors(*,i)=interpolate(tabl,ix,iy)
endfor

teff=teffo
logg=loggo

end